Google Sheets kan bruges til mere end blot dataopsamling og organisering. Du kan også bruge det til at bestemme det aktuelle tidspunkt, oprette diagrammer og beregne alder ved hjælp af en fødselsdato. Sidstnævnte opdages ved brug af formler og funktioner indbygget direkte i Google Sheets.
Alderbestemmelse ud fra fødselsdato i Google Sheets
Når du bruger Google Sheets, har du to overvejende måder, hvorpå du kan bestemme alder ud fra en fødselsdato. Der er DATEDIF , som er den mere fleksible mulighed, og ÅRFRAC , det nemmere valg. Ved slutningen af artiklen bør du være i stand til at bestemme ikke kun alderen på et enkelt individ, men alderen på flere grupper af forskellige mennesker på én gang.
Jeg starter tingene med DATEDIF-funktionen.
DATEDIF-funktionen
Før vi kan dykke ned i selve funktionen, skal vi vide, hvordan den fungerer. Dette vil kræve at lære syntaksen til brug med DATEDIF-funktionen. Hver sektion, du har indtastet i funktionen, korrelerer med en opgave, se disse opgaver nedenfor:
Syntaks
=DATEDIF(startdato;slutdato;enhed)
- start dato
- Beregningen skal begynde med fødselsdatoen.
- slutdato
- Dette vil være datoen for at afslutte beregningen. Når man bestemmer den aktuelle alder, vil dette tal sandsynligvis være dagens dato.
- enhed
- Udgangsvalgene, der består af: 'Y',,'M',,'D',,'YM',,'YD', eller 'MD'.
- Y – Samlet antal fulde, forløbne år mellem de indtastede start- og slutdatoer.
- YM - 'M'et' står i måneder. Dette output viser antallet af måneder efter de fuldt forløbne år for 'Y'. Antallet vil ikke overstige 11.
- YD - 'D'et' står for dage. Dette output viser antallet af dage efter de fuldt forløbne år for 'Y'. Antallet vil ikke overstige 364.
- M – Det samlede antal fuldt forløbne måneder mellem de indtastede start- og slutdatoer.
- MD – Ligesom i de andre enheder står 'D' for dage. Dette output viser antallet af dage efter de fuldt forløbne måneder for 'M'. Kan ikke overstige 30.
- D – Det samlede antal fuldt forløbne dage mellem de indtastede start- og slutdatoer.
Beregningen
Nu hvor du forstår den syntaks, der vil blive brugt, kan vi opsætte formlen. Som tidligere nævnt er DATEDIF-funktionen den mere fleksible mulighed, når man skal bestemme alder ud fra en fødselsdato. Grunden til dette er, at du kan beregne alle detaljer om alderen i et år, måned og dagsformat.
Til at begynde med har vi brug for en eksempeldato, der skal bruges i cellen. Jeg har besluttet at placere datoen 14.7.1972 ind i cellen A1 . Vi laver formlen i cellen til højre for den, B1 , hvis du vil følge med for at få styr på det.
Vi starter med den mest grundlæggende version af formlen for at beregne alderen. Hvis du bruger ovenstående syntaks til at finde ud af, hvad der er hvad, A1 er teknisk set start dato , i dag vil være slutdato , og vi bestemmer alderen i år ved hjælp af 'Y' . Derfor vil den første formel, der bliver brugt, se sådan ud:
=datedif(A1,today(),"Y")
hvordan man kan se, hvad folk kunne lide på instagram 2020
Nyttigt tip: Kopier og indsæt formlen direkte i B2, og tryk på Enter for at modtage det relevante output.
Når det er gjort korrekt, vil tallet, der angiver den beregnede alder, være placeret i B1 som '46'.
Lad os gøre den samme formel, kun denne gang bestemmer vi alderen i måneder ved hjælp af 'M' i stedet for 'Y'.
=datedif(A1,today(),"M")
Det samlede beløb ville være 559 måneder. Det er 559 måneder gammelt.
Dette tal er dog lidt absurd, og jeg tror, vi kan tage det et hak ned ved at bruge 'I' i stedet for blot 'M'.
=datedif(A1,today(),"YM")
Det nye resultat skulle være 7, hvilket er et meget mere overskueligt tal.
Bare for at være grundig, lad os se, hvordan dagene vil se ud ved at bruge både 'YD' og 'MD'.
=datedif(A1,today(),"YD")
=datedif(A1,today(),"MD")
Denne gang vises resultaterne for 'YD' i B1, og resultatet for 'MD' er placeret i celle B2.
Har du fået styr på det indtil videre?
Dernæst samler vi disse alle sammen i et forsøg på at give os selv en mere detaljeret beregning. Formlen kan blive lidt hektisk at skrive ud, så bare kopier og indsæt den medfølgende i celle B1.
Formlen der skal bruges er:
hvordan man fjerner nogen fra en gruppetekst
=datedif(A1,today(),"Y")&" Years "&datedif(A1,today(),"YM")&" months & "& datedif(A1,today(),"MD")&" days"
Et-tegnet bruges til at forbinde hver formel sammen som et kædeled. Dette er nødvendigt for at få den fulde beregning. Dit Google Sheet skal indeholde den samme formel som:
En fuldstændig, detaljeret beregning har givet os 46 år, 7 måneder og 26 dage. Du kan også bruge den samme formel ved hjælp af ArrayFormula-funktionen. Det betyder, at du kan beregne mere end blot en enkelt dato, men også flere datoer.
Jeg har valgt et par datoer tilfældigt og sat dem i yderligere celler A2-A5 . Vælg dine egne datoer og hav det lidt sjovt med det. For at bruge ArrayFormula-funktionen skal du kopiere og indsætte følgende i celle B1:
=ArrayFormula(datedif(A1:A5,today(),"Y")&" Years "&datedif(A1:A5,today(),"YM")&" months & "& datedif(A1:A5,today(),"MD")&" days")
Dette er mine resultater:
Lad os nu sige, at du ønskede at adskille hver del af datoen i sin egen pæne lille kolonne for at organisere skyld. I Google Sheets skal du tilføje din startdato (fødselsdatoen) i én kolonne og slutdatoen i en anden. Jeg har valgt celle B2 for start_date og C2 for end_date i mit eksempel. Mine datoer korrelerer med fødsler og nylige dødsfald af berømtheder Burt Reynolds, Johnny Cash og Luke Perry.
Som vist er kolonne A navnet på individet, kolonne B indeholder startdatoen og C slutdatoen. Nu tilføjer jeg yderligere fire kolonner til højre. En for hver af 'Y', 'YM', 'YD', og en kombination af alle tre. Nu skal du bare tilføje de korrekte formler til hver række for hver berømthed.
Burt Reynolds:
=DATEDIF(B2,C2,"Y") Skift 'Y' til den tilsvarende kolonne, du forsøger at beregne.
Johnny Cash:
=DATEDIF(B3,C3,"Y") Skift 'Y' til den tilsvarende kolonne, du forsøger at beregne.
Luke Perry:
=DATEDIF(B4,C4,"Y") Skift 'Y' til den tilsvarende kolonne, du forsøger at beregne.
For at få JOINED-formlen skal du bruge en ArrayFormula ligesom vi gjorde tidligere i artiklen. Du kan tilføje ord som f.eks Flere år at angive årenes resultater ved at placere det efter formlen og mellem parenteser.
=ArrayFormula(datedif(B2,C2,"Y")&" Years "&datedif(B2,C2,"YM")&" months & "& datedif(B2,C2,"MD")&" days")
hvordan man ændrer pdf-tekstfarve
Ovenstående formel er pr. berømthed. Men hvis du bare vil slå dem alle ud i ét hug, kopier og indsæt følgende formel i celle G2:
=ArrayFormula(datedif(B2:B4,C2:C4,"Y")&" Years "&datedif(B2:B4,C2:C4,"YM")&" months & "& datedif(B2:B4,C2:C4,"MD")&" days")
Dit Google Sheet skulle ende med at se sådan her ud:
Ret pænt, hva'? Det er virkelig så enkelt, når du bruger DATEDIF-funktionen. Nu kan vi gå videre til at bruge YEARFRAC-funktionen.
YEARFRAC-funktionen
YEARFRAC-funktionen er enkel til enkle resultater. Det er lige til punktet og giver et slutresultat uden alle de ekstra tilføjede output i år, måneder og dage.
Her er en grundlæggende formel, der kun gælder for en enkelt celle:
=int(YEARFRAC(A1,today()))
Du tilføjer fødselsdatoen til celle A1 og indsætter formlen i B1 for resultatet. Vi bruger fødselsdatoen 04/11/1983 :
Resultatet er 35 år. Simpelt, ligesom når du bruger DATEDIF-funktionen til en enkelt celle. Herfra kan vi gå videre til at bruge YEARFRAC i en ArrayFormula. Denne formel er mere nyttig for dig, når du skal beregne alderen på store grupper som studerende, fakultetsmedlemmer, teammedlemmer osv.
Vi bliver nødt til at tilføje en kolonne med forskellige fødselsdatoer. Jeg har valgt kolonne B, da A vil blive brugt til navnene på personerne. Kolonne C vil blive brugt til slutresultaterne.
For at udfylde alderen i den tilstødende kolonne, skal vi bruge følgende formel:
=ArrayFormula(int(yearfrac(B2:B8,today(),1)))
Placer formlen ovenfor i celle C2 for at få resultaterne.
Hvis du hellere bare vil fortsætte med en hel kolonne og helst ikke gider at finde ud af, hvor den ender, kan du tilføje en lille variation til formlen. Slå på IF og LEN mod begyndelsen af ArrayFormula sådan:
=ArrayFormula(if(len(B2:B),(int(yearfrac(B2:B,today(),1))),))
Dette vil beregne alle resultaterne i den kolonne begyndende fra B2.
